如何使用批处理脚本创建快捷方式？

你可以通过创建一个临时的VBScript来实现，不需要外部工具：

@echo off

set SCRIPT="%TEMP%\%RANDOM%-%RANDOM%-%RANDOM%-%RANDOM%.vbs"

echo Set oWS = WScript.CreateObject("WScript.Shell") >> %SCRIPT%
echo sLinkFile = "%USERPROFILE%\Desktop\myshortcut.lnk" >> %SCRIPT%
echo Set oLink = oWS.CreateShortcut(sLinkFile) >> %SCRIPT%
echo oLink.TargetPath = "D:\myfile.extension" >> %SCRIPT%
echo oLink.Save >> %SCRIPT%

cscript /nologo %SCRIPT%
del %SCRIPT%

(想法来自于这里.)

这将在桌面上创建myshortcut.lnk，指向D:\myfile.extension。

在保存链接之前，你可以通过修改下面的值来提供额外的属性：

oLink.Arguments
oLink.Description
oLink.HotKey
oLink.IconLocation
oLink.WindowStyle
oLink.WorkingDirectory

请参考 如何使用 Windows 脚本主机创建桌面快捷方式 查看一些例子。

@echo off
echo [InternetShortcut] >> "%AllUsersProfile%\desktop\NOTEPAD.url"
echo URL="C:\WINDOWS\NOTEPAD.EXE" >> "%AllUsersProfile%\desktop\NOTEPAD.url"
echo IconFile=C:\WINDOWS\system32\SHELL32.dll >> "%AllUsersProfile%\desktop\NOTEPAD.url"
echo IconIndex=20 >> "%AllUsersProfile%\desktop\NOTEPAD.url"

这段代码在 “所有用户 "桌面文件夹中创建了一个名为NOTEPAD.url的快捷方式，指向NotePad应用程序，并将从SHELL32.dll中分配一个图标。将路径和文件名改成你的D:/位置和外文名。并确保你的.url文件名在所有代码行中保持一致。

有一个外部命令shortcut.exe可以这样做：

shortcut /a:c /f:"c:\users\me\desktop\myshortcut.lnk" /t:"c:\program files\skype\skype.exe"

可以在你的桌面上创建skype的快捷方式

是免费下载的程序，但我找不到它的链接，所以我会尝试上传并贴出链接

这里是： shortcut.exe by Marty List